#261 Testing JavaScript with Jasmine (revised)

mkdir -p spec/javascripts
brew install phantomjs
guard init jasmine

group :development, :test do
  gem 'jasminerice'
  gem 'guard-jasmine'
end

#= require jquery
#= require credit_card
#= require_tree .

describe "CreditCard", ->
  it "strips out spaces and dashes from number", ->
    card = new CreditCard("1 2-3")
    expect(card.number).toBe("123")

  it "validates number using mod 10", ->
    validCard = new CreditCard("4111-1111-1111 1111")
    invalidCard = new CreditCard("4111111111111112")
    expect(validCard.validNumber()).toBeTruthy()
    expect(invalidCard.validNumber()).toBeFalsy()
    
  it "validates number when field loses focus", ->
    loadFixtures "order_form"
    field = $('#card_number')
    field.validateCreditCardNumber()
    field.val('123')
    field.blur()
    expect(field.next('.error')).toHaveText("Invalid card number.")
    field.val('4111-1111-1111 1111')
    field.blur()
    expect(field.next('.error')).toHaveText("")

class @CreditCard
  constructor: (number) ->
    @number = number.replace(/[ -]/g, '')
  
  validNumber: ->
    total = 0
    for i in [(@number.length-1)..0]
      n = +@number[i]
      if (i+@number.length) % 2 == 0
        n = if n*2 > 9 then n*2 - 9 else n*2
      total += n
    total % 10 == 0


$.fn.validateCreditCardNumber = ->
  @each ->
    $(this).blur ->
      card = new CreditCard(@value)
      if !card.validNumber()
        $(this).next('.error').text("Invalid card number.")
      else
        $(this).next('.error').text("")

jQuery ->
  $('#order_card_number').validateCreditCardNumber()